【マイクラ】バッチファイルをカスタマイズしてみた【配布あり】

@echo off
color e0
title バッチファイルでマイクラサーバー自動構築
echo         #+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+#
echo         #                                                             #
echo         #        ＼バッチファイルでマイクラサーバー自動構築／         #
echo         #       質問形式で簡単にサーバー構築するバッチファイル        #
echo         #                 対応Ver 1.12.2-1.16.5                       #
echo         #      製作:揚げたてのポテト  Web:https://agepote.jp       #
echo         #                   製作日：2021/04/01                        #
echo         #                                                             #
echo         #+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+#
if exist server-1.12.2.jar (
    set VER=1.12.2
    goto :START
)else if exist server-1.13.2.jar (
    set VER=1.13.2
    goto :START
)else if exist server-1.14.4.jar (
    set VER=1.14.4
    goto :START
)else if exist server-1.15.2.jar (
    set VER=1.15.2
    goto :START
)else if exist server-1.16.5.jar (
    set VER=1.16.5
    goto :START
)else (
    goto :SETUP
)

:START
cd /d %~dp0
title バッチファイルでマイクラサーバー自動構築 [%VER%]
echo;
echo セットアップ確認完了
echo;
echo サーバー起動中...
echo しばらくお待ちください...
java -jar -Xms1024M -Xmx1024M server-%VER%.jar nogui
goto :EXIT

:SETUP
cd /d %~dp0
echo;
echo [注意] サーバー設定が完了するとバッチファイルと同じフォルダにサーバーファイルが生成されます！
echo [推奨] 新しいフォルダにバッチファイルを入れてから進めることをオススメします！(再起動必須)
echo;

:STEP1
echo [STEP1] サーバーファイルの生成を開始してもよろしいですか？[はい:y,いいえ:n]
set INPUT=
set /P INPUT="入力>> "
if "%INPUT%"=="y" (
    echo ■サーバーファイルの生成を開始します
    goto :STEP2
) else if "%INPUT%"=="n" (
    goto :EXIT
) else (
    echo [警告] yまたはnで入力してください！
    goto :STEP1
)

:STEP2
echo;
echo;
if exist eula.txt del eula.txt
echo [STEP2] Minecraft EULA（https://bit.ly/2OoJY69）に同意しますか？[はい:y,いいえ:n]
set INPUT=
set /p INPUT="入力>> "
if "%INPUT%"=="y" (
    echo #EULAをtrueに変更すると、Minecaft EULA（https://bit.ly/2OoJY69）に同意したことになります。>> eula.txt
    echo #Sun Jan 1 00:00:00 JST 2021>> eula.txt
    echo eula=true>> eula.txt
    echo ■EULAに同意しました
    goto :STEP3
) else if "%INPUT%"=="n" (
    echo #EULAをtrueに変更すると、Minecaft EULA（https://bit.ly/2OoJY69）に同意したことになります。>> eula.txt
    echo #Sun Jan 1 00:00:00 JST 2021>> eula.txt
    echo eula=false>> eula.txt
    echo ■EULAに同意しませんでした
    goto :EXIT
) else (
    echo [警告] yまたはnで入力してください！
    goto :STEP2
)

:STEP3
echo;
echo;
echo [STEP3] サーバーの設定を行います

:VER
echo;
echo 1.サーバーのバージョンはいくつにしますか？[1.12.2:a,1.13.2:b,1.14.4:c,1.15.2:d,1.16.5:e]
set VER=
set /p VER="入力>> "
if "%VER%"=="a" (
    set VER=1.12.2
) else if "%VER%"=="b" (
    set VER=1.13.2
) else if "%VER%"=="c" (
    set VER=1.14.4
) else if "%VER%"=="d" (
    set VER=1.15.2
) else if "%VER%"=="e" (
    set VER=1.16.5
) else (
    echo [警告] a,b,c,d,eで入力してください！
    goto :VER
)
title バッチファイルでマイクラサーバー自動構築 [%VER%]
echo ■サーバーのバージョンを「%VER%」に設定しました

:NAME
echo;
echo 1.サーバーの名前は何にしますか？[サーバー名(motd):名前]
set NAME=
set /p NAME="入力>> "
echo ■サーバーの名前を「%NAME%」に設定しました

:PORT
echo;
echo 2.サーバーのポート番号は何にしますか？[デフォルト:d]
set PORT=
set /p PORT="入力>> "
if "%PORT%"=="d" (
    set PORT=25565
)
echo ■サーバーのポート番号を「%PORT%」に設定しました

:GAMEMODE
echo;
echo 3.ゲームモードの設定は何にしますか？[サバイバル:s,アドベンチャー:a,クリエイティブ:c]
set GAMEMODE=
set /p GAMEMODE="入力>> "
if "%GAMEMODE%"=="s" (
    set GAMEMODE=survival
) else if "%GAMEMODE%"=="a" (
    set GAMEMODE=adventure
) else if "%GAMEMODE%"=="c" (
    set GAMEMODE=creative
) else (
    echo [警告] s,a,cで入力してください！
    goto :GAMEMODE
)
echo ■ゲームモードを「%GAMEMODE%」に設定しました

:DIFFICULTY
echo;
echo 4.難易度の設定は何にしますか？[ピースフル:p,イージー:e,ノーマル:n,ハード:h,ハードコア:hc]
set DIFFICULTY=
set /p DIFFICULTY="入力>> "
if "%DIFFICULTY%"=="p" (
    set DIFFICULTY=peaceful
) else if "%DIFFICULTY%"=="e" (
    set DIFFICULTY=easy
) else if "%DIFFICULTY%"=="n" (
    set DIFFICULTY=nomal
) else if "%DIFFICULTY%"=="h" (
    set DIFFICULTY=hard
) else if "%DIFFICULTY%"=="hc" (
    set DIFFICULTY=hard
    set HARDCORE=true
) else (
    echo [警告] p,e,n,h,hcで入力してください！
    goto :DIFFICULTY
)
echo ■難易度を「%DIFFICULTY%」に設定しました

:SEED
echo;
echo 5.シード値の設定は何にしますか？[空白:ランダム]
set SEED=
set /p SEED="入力>> "
if "%SEED%"=="" (
    echo ■シード値を「ランダム」に設定しました
)else (
    echo ■シード値を「%SEED%」に設定しました
)

:MAX_PRAYERS
echo;
echo 6.最大参加人数の設定は何にしますか？[デフォルト（20人）:d]
set MAX_PRAYERS=
set /p MAX_PRAYERS="入力>> "
if "%MAX_PRAYERS%"=="d" set MAX_PRAYERS=20
echo ■最大参加人数を「%MAX_PRAYERS%」に設定しました

:PVP
echo;
echo 7.PVPの設定は何にしますか？[PVP可能:on,PVP不可:off]
set PVP=
set /p PVP="入力>> "
if "%PVP%"=="on" (
    set PVP=true
) else if "%PVP%"=="off" (
    set PVP=false
) else (
    echo [警告] onまたはoffで入力してください！
    goto :PVP
)
echo ■PVPを「%PVP%」に設定しました

:FRY
echo;
echo 8.フライを許可しますか？[はい:y,いいえ:n]
set FRY=
set /p FRY="入力>> "
if "%FRY%"=="y" (
    set FRY=true
) else if "%FRY%"=="n" (
    set FRY=false
) else (
    echo [警告] yまたはnで入力してください！
    goto :FRY
)
echo ■フライの許可を「%FRY%」に設定しました

:STEP4
echo;
echo [STEP4] サーバー設定の確認
echo #########################################
echo      サーバーのバージョン ： %VER%
echo      サーバーの名前 : %NAME%
echo      ポート番号 : %PORT%
echo      ゲームモード : %GAMEMODE%
echo      難易度 : %DIFFICULTY%
echo      シード値 : %SEED%(空白はランダム)
echo      最大参加人数 : %MAX_PRAYERS%
if "%PVP%"=="true" (
    echo      PVP : 可
) else (
    echo      PVP : 不可
)
if "%FRY%"=="false" (
    echo      フライ許可 : 不可
) else (
    echo      フライ許可 : 可
)
echo #########################################

:STEP5
echo;
echo [STEP5] 上記のサーバー設定でよろしいですか？[はい:y,いいえ:n]
set INPUT=
set /p INPUT="入力>> "
if "%INPUT%"=="y" (
    goto :PROPERTIES
) else if "%INPUT%"=="n" (
    goto :STEP3
) else (
    echo [警告] yまたはnで入力してください！
    goto :STEP5
)

:PROPERTIES
if exist server.properties del server.properties
echo サーバー設定を書き込み中...
echo #Minecraft server properties>> server.properties
echo #Sun Jan 1 00:00:00 JST 2021>> server.properties
echo spawn-protection=16>> server.properties
echo max-tick-time=60000>> server.properties
echo query.port=%PORT%>> server.properties
echo generator-settings= >> server.properties
echo sync-chunk-writes=true>> server.properties
echo force-gamemode=false>> server.properties
echo allow-nether=true>> server.properties
echo enforce-whitelist=false>> server.properties
echo gamemode=%GAMEMODE%>> server.properties
echo broadcast-console-to-ops=true>> server.properties
echo enable-query=false>> server.properties
echo player-idle-timeout=0>> server.properties
echo difficulty=%DIFFICULTY%>> server.properties
echo broadcast-rcon-to-ops=true>> server.properties
echo spawn-monsters=true>> server.properties
echo op-permission-level=4>> server.properties
echo pvp=%PVP%>> server.properties
echo entity-broadcast-range-percentage=100>> server.properties
echo snooper-enabled=true>> server.properties
echo level-type=default>> server.properties
echo enable-status=true>> server.properties
echo hardcore=%HARDCORE%>> server.properties
echo enable-command-block=false>> server.properties
echo network-compression-threshold=256>> server.properties
echo max-players=%MAX_PRAYERS%>> server.properties
echo max-world-size=29999984>> server.properties
echo resource-pack-sha1= >> server.properties
echo function-permission-level=2>> server.properties
echo rcon.port=25575>> server.properties
echo server-port=%PORT%>> server.properties
echo server-ip= >> server.properties
echo spawn-npcs=true>> server.properties
echo allow-flight=%FRY%>> server.properties
echo level-name=world>> server.properties
echo view-distance=10>> server.properties
echo resource-pack= >> server.properties
echo spawn-animals=true>> server.properties
echo white-list=false>> server.properties
echo rcon.password= >> server.properties
echo generate-structures=true>> server.properties
echo online-mode=true>> server.properties
echo max-build-height=256>> server.properties
echo level-seed=%SEED%>> server.properties
echo prevent-proxy-connections=false>> server.properties
echo use-native-transport=true>> server.properties
echo enable-jmx-monitoring=false>> server.properties
echo motd=%NAME%>> server.properties
echo rate-limit=0>> server.properties
echo enable-rcon=false>> server.properties

:DL
echo;
echo;
echo サーバーファイルのダウンロード中...
if "%VER%"=="1.12.2" (
bitsadmin /TRANSFER fileget https://launcher.mojang.com/v1/objects/886945bfb2b978778c3a0288fd7fab09d315b25f/server.jar %CD%/server-1.12.2.jar
) else if "%VER%"=="1.13.2" (
bitsadmin /TRANSFER fileget https://launcher.mojang.com/v1/objects/3737db93722a9e39eeada7c27e7aca28b144ffa7/server.jar %CD%/server-1.13.2.jar
) else if "%VER%"=="1.14.4" (
bitsadmin /TRANSFER fileget https://launcher.mojang.com/v1/objects/3dc3d84a581f14691199cf6831b71ed1296a9fdf/server.jar %CD%/server-1.14.4.jar
) else if "%VER%"=="1.15.2" (
bitsadmin /TRANSFER fileget https://launcher.mojang.com/v1/objects/bb2b6b1aefcd70dfd1892149ac3a215f6c636b07/server.jar %CD%/server-1.15.2.jar
) else if "%VER%"=="1.16.5" (
bitsadmin /TRANSFER fileget https://launcher.mojang.com/v1/objects/1b557e7b033b583cd9f66746b7a9ab1ec1673ced/server.jar %CD%/server-1.16.5.jar
)
goto :START

:EXIT
echo;
echo;
if exist server-1.12.2.jar (
    exit
)else if exist server-1.13.2.jar (
    exit
)else if exist server-1.14.4.jar (
    exit
)else if exist server-1.15.2.jar (
    exit
)else if exist server-1.16.5.jar (
    exit
)
echo バッチファイル終了してもよろしいですか？[はい:y,いいえ:n]
set INPUT=
set /p INPUT="入力>> "
if "%INPUT%"=="y" (
exit
) else if "%INPUT%"=="n" (
goto :SETUP
)else (
echo [警告] yまたはnで入力してください！
goto :EXIT
)